Using raylib + raygui with Zig

Showcase
1

Hi everyone.

I’ve recently been trying to link raylib and raygui to an emulator project I’ve been working on. It was quite a journey, I’m very new to zig and things are changing pretty quickly so resources about the new way to do things are sparse. But I was able to get it working and I thought I’d share in case it may help anybody else. Currently I’m using zig 0.13, raylib tag 5.5 and raygui tag 4.0. There was a little bug in the build.zig of raylib 5.5 that I had to work around, but it’s fixed in master. You’ll see the work around in my build.zig example.

I’m pretty new to zig, and build systems in general, so open to any feedback on if there are better ways to do this.

// build.zig
const std = @import("std");
const raylib_build = @import("raylib");

pub fn build(b: *std.Build) void {
    const target = b.standardTargetOptions(.{});
    const optimize = b.standardOptimizeOption(.{});
    
    const exe = b.addExecutable(.{
        .name = "myexe",
        .root_source_file = b.path("src/main.zig"),
        .target = target,
        .optimize = optimize,
    });
    b.installArtifact(exe);

    // Add raylib and raygui dependencies ------------------------------------
    const raylib_dep = b.dependency("raylib", .{
        .target = target,
        .optimize = optimize,
        .shared = true,
    });
    const raylib = raylib_dep.artifact("raylib");

    const raygui_dep = b.dependency("raygui", .{});
    raylib_build.addRaygui(b, raylib, raygui_dep);

    // NOTE: This line is not included in `addRaygui` in tag 5.5 but is in master.
    //  Try removing it next time you upgrade raylib dependency.
    raylib.addIncludePath(raylib_dep.path("src"));

    exe.linkLibrary(raylib);
    b.installArtifact(raylib);
    //------------------------------------------------------------------------

    const run_cmd = b.addRunArtifact(exe);
    run_cmd.step.dependOn(b.getInstallStep());

... rest of you build.zig here

// build.zig.zon
.{
    .name = "myexe",
    .version = "0.0.1",
    .minimum_zig_version = "0.13.0",
    .dependencies = .{
        .raylib = .{
            .url = "git+https://github.com/raysan5/raylib.git?ref=5.5#c1ab645ca298a2801097931d1079b10ff7eb9df8",
            .hash = "1220d93782859726c2c46a05450615b7edfc82b7319daac50cbc7c3345d660b022d7",
        },
        .raygui = .{
            .url = "git+https://github.com/raysan5/raygui.git?ref=4.0#25c8c65a6e5f0f4d4b564a0343861898c6f2778b",
            .hash = "1220b64eaeaf55609b3152b64d108ea73981c9689e783bddc68c80e77d275ebac164",
        },
    },
    .paths = .{
        "build.zig",
        "build.zig.zon",
        "src",
        "LICENSE",
        "README.md",
    },
}

// src/main.zig
const std = @import("std");
const raylib = @cImport({
    @cInclude("raylib.h");
    @cInclude("raygui.h");
});

pub fn main() !void {
    raylib.InitWindow(800, 450, "Raylib Test");
    raylib.SetTargetFPS(60);

    var showMessageBox = false;
    const button_pos = raylib.Rectangle{
        .x = 24,
        .y = 24,
        .width = 120,
        .height = 30,
    };
    const box_pos = raylib.Rectangle{
        .x = 85,
        .y = 70,
        .width = 250,
        .height = 100,
    };

    while (!raylib.WindowShouldClose()) {
        raylib.BeginDrawing();
        raylib.ClearBackground(raylib.RAYWHITE);
        raylib.DrawText("Raylib from zig!", 190, 200, 20, raylib.LIGHTGRAY);

        if (raylib.GuiButton(button_pos, "#191#Show Message!") > 0)
            showMessageBox = true;

        if (showMessageBox) {
            const result = raylib.GuiMessageBox(
                box_pos,
                "#191#Message Box",
                "Hi! This is a Message!",
                "Nice!;Cool!",
            );

            if (result >= 0)
                showMessageBox = false;
        }

        raylib.EndDrawing();
    }

    raylib.CloseWindow();
}
2 Likes
2

Welcome to Ziggit @jakesco!

Why do you use raygui tag 4.0?
It is quite old, I would use one of the more recent commits instead.
I imagine you could encounter problems with api mismatches between raylib 5.5 and raygui 4.0.

Other then that it seems pretty similar to my raygui branch in this example:

But so far I am not a very active user of raygui, just added a branch because somebody asked about it, so I don’t know that much about raygui usage in practice.

3

Hey thanks for the link! I’ll give your repo a look.

I picked 4.0 because that was the latest tagged release. I see now that it’s a year old but I wanted a somewhat stable setup. I’ll definitely keep it in mind, if I run into issue I may upgrade.

1 Like