Require specific zig version in build script

[kj4tmp]

Is it possible to require a specific version of zig in my build script?

Here is the concrete use case:

In industrial controls, a project is finished and shipped to the customer, not touched for a long time, and then small changes are required, and the cycle repeats. It would perhaps be beneficial to enforce the version of the compiler used as part of the build system so I would not have to remember to read it from the README. The best documentation is code right

[kj4tmp]

Aha it’s in builtin

Build version information

Is it possible to access zig compiler version inside zig code? I want something like “0.11.0-dev.980+601ab9a25” to be included inside my code. I don’t see anything related in builtin.zig and grep didn’t find anything with ‘0.11.0’ string inside installed files. Workaround would be to have build.zig to generate that information inside file which could be included later.

[Sze]

From Build System Tricks :

@tensorush

3) Dependence on the Zig Compiler version

const builtin = @import("builtin");

comptime {
    const required_zig = "0.12.0-dev.3302";
    const current_zig = builtin.zig_version;
    const min_zig = std.SemanticVersion.parse(required_zig) catch unreachable;
    if (current_zig.order(min_zig) == .lt) {
        const error_message =
            \\Sorry, it looks like your version of zig is too old. :-(
            \\
            \\(Insert your program name here) requires development build {}
            \\
            \\Please download a development ("master") build from
            \\
            \\https://ziglang.org/download/
            \\
            \\
        ;
        @compileError(std.fmt.comptimePrint(error_message, .{min_zig}));
    }
}

[kj4tmp]

Exact solution:

comptime {
    const required_zig_version = "0.13.0";
    const zig_version = @import("builtin").zig_version_string;
    if (!std.mem.eql(u8, required_zig_version, zig_version)) @compileError("This project requires zig version: " ++ required_zig_version ++ ", your zig version is: " ++ zig_version);
}

[mnemnion]

I want to note that it’s also possible to provide build-specific steps based on the Zig version, and even gate logic within the package based on it, since builtin is available there as well.

I’ve found that pretty useful for minor differences between 0.13 and the master branch, although if the Type enum tag is involved, I’ve just given up and picked a lane. It wouldn’t be impossible even there, but the amount of comptime magic involved gets pretty gnarly.

With 0.14 around the corner, you might find that useful or even essential for supporting the longer deploy cycle in embedded contexts, while handling the fact that Zig tends to move quickly, and most users are going to update to the next release version accordingly.

[castholm]

@mnemnion

I’ve found that pretty useful for minor differences between 0.13 and the master branch, although if the Type enum tag is involved, I’ve just given up and picked a lane. It wouldn’t be impossible even there, but the amount of comptime magic involved gets pretty gnarly.

Slightly off-topic, but I’ll just mention that shimming @typeInfo and std.builtin.Type isn’t that crazy difficult. @InKryption suggested the following to me and it has let me painlessly support both 0.13.0 and 0.14.0-dev just by replacing uses of @typeInfo with shims.typeInfo:

castholm/zigglgen/blob/701f41808086411f14d3bc2d87fc0b14bd09ceba/shims.zig

(It’s missing @Type because my project didn’t need it, but would more or less just be the inverse of the switch in the @typeInfo shim.)